Open Mash Cross Reference
mash/tcl/degas/degasserver/degas-session.tcl

   import NetworkManager
   
   DegasSession instproc init {agent spec} {
           $self next 0 0
           $self instvar agent_ netmgr_ 
           set agent_ $agent
           set netmgr_ null
           set address_block [new AddressBlock $spec/1]
           $self reset $address_block
          delete $address_block
  }
  
  DegasSession instproc reset {addrblock} {
          $self instvar agent_ netmgr_
  
          if {$netmgr_ != "null"} {
                  delete $netmgr_
          }
          set netmgr_ [new NetworkManager $addrblock $self $agent_]
  
          for {set i 0} {$i < [$netmgr_ nchan]} {incr i} {
                  set net [$netmgr_ set net_($i)]
                  [$net data-net] loopback 1
                  [$net ctrl-net] loopback 1
          }
  }
  
  DegasSession instproc destroy {} {
          $self instvar netmgr_ 
          if {$netmgr_ != "null"} {
                  delete $netmgr_
          }
  
  #   Clear all bandwidth counters
          $self instvar start_nb_
          global bps_
          foreach src [array names start_nb_] {
                  unset start_nb_($src)
                  unset bps_($src,$self)
          }
  
          $self next
  }
  
  DegasSession instproc get {item} {
          return "$self$item"
  }
  
  
  DegasSession instproc recv_sr {source latency num_of_bytes} {
          $self instvar agent_ start_nb_ 
  
  #   We compute the bandwidth of the input source $source by
  #   looking at the $num_of_bytes (sr_nb field of a SR RTCP packet).   
  #   This gives us the total number of bytes sent since the source
  #   start sending.  Since we are using a rate_variable (from tclcl)
  #   to compute the bandwidth, we need to keep track of the number of
  #   bytes  the source has sent when we join its session.
  
          global bps_
          if {![info exists bps_($source,$self)]} {
                  # This is the first time we see this source.
                  # Remember the value "num_of_bytes"
                  rate_variable bps_($source,$self) 0.1
                  set start_nb_($source) $num_of_bytes
                  puts "reset bps_ ($source) [$self set start_nb_($source)]"
                  set bps_($source,$self) 0
          } else {
                  set bps_($source,$self) [expr $num_of_bytes - $start_nb_($source)]
          }
          if {[$agent_ info vars aglp_] != ""} {
                  set aglp [$agent_ set aglp_]
                  $aglp set_bandwidth $source $bps_($source,$self)
                  $aglp set_latency $source $latency
          }
  }