Open Mash Cross Reference
mash/tcl/common/mash-softstate.tcl

   import MashTimer
   import MashLog
   
   Class MashSoftState
   
   #----------------------------------------------------------------------
   # Class:
   #   MashSoftState
   # Description:
  #   A MashSoftState object is an abstraction for a soft state variable, 
  #   commonly used in writing light-weight, loosely coupled protocol.  
  #   It contains a data value, a timeout value t, and a callback f.  
  #   When the value is set, a timer is started.  The timer timeout after 
  #   t seconds, after which the value expires, and callback f is called.  
  #----------------------------------------------------------------------
  #
  # The following interface is provided by this class. 
  # - set_value : set the value of the state & the timer is reset.
  # - get_value : retrieve the value of the state & the timer is unchange.
  # - refresh   : reset the timer without changing the value
  # - expire    : force the timer the expire but keep the value unchanged.
  # - is_expired : test if the timer has expired.
  #
  
  #----------------------------------------------------------------------
  # Method:
  #   MashSoftState init
  # Description:
  #   Create a new soft-state with value $value and timeout $timeout.
  #   $callback will be called if $timeout has passed without a refresh.
  #----------------------------------------------------------------------
  MashSoftState public init { value timeout callback } {
      $self instvar value_ timeout_ timer_ callback_ expired_
      set value_ $value
      set timeout_ $timeout
      set callback_ $callback
      set timer_ [new MashTimer "once" $timeout "$self expire"]
      set expired_ 0
  }
  
  
  #----------------------------------------------------------------------
  # Method:
  #   MashSoftState set_value
  # Description:
  #   Set the value of the state.  The soft state is refreshed.  If the
  #   state has expired, "unexpire" the state.
  #----------------------------------------------------------------------
  MashSoftState public set_value { value } {
      $self instvar value_ expired_
      set value_ $value
      $self refresh
      set expired_ 0
  }
  
  
  #----------------------------------------------------------------------
  # Method:
  #   MashSoftState get_value
  # Description:
  #   Return the value of the state.
  #----------------------------------------------------------------------
  MashSoftState public get_value { } {
      $self instvar value_
      return $value_ 
  }
  
  
  #----------------------------------------------------------------------
  # Method:
  #   MashSoftState refresh
  # Description:
  #   Refresh the soft state.
  #----------------------------------------------------------------------
  MashSoftState public refresh { } {
      $self instvar timer_ timeout_ callback_
      $timer_ resched
  }
  
  
  #----------------------------------------------------------------------
  # Method:
  #   MashSoftState expire
  # Description:
  #   Called when this state expired.
  #----------------------------------------------------------------------
  MashSoftState public expire { } {
      $self instvar timer_ callback_ expired_
      $timer_ cancel
      set expired_ 1
      eval $callback_
  }
  
  
  #----------------------------------------------------------------------
  # Method:
  #   MashSoftState is_expired
  # Description:
  #   Test if the current state has expired.  
 #----------------------------------------------------------------------
 MashSoftState public is_expired { } {
     $self instvar expired_
     return $expired_
 }
 
 
 #----------------------------------------------------------------------
 # Method:
 #   MashSoftState destroy
 # Description:
 #   Delete the timer.
 #----------------------------------------------------------------------
 MashSoftState public destroy {} {
     $self instvar timer_
     delete $timer_
     $self next
 }
 
 
 #----------------------------------------------------------------------
 # Class:
 #   MashSoftState/Adaptive
 # Description:
 #   Maintain average refresh interval I, and timeout after N*I second.
 #----------------------------------------------------------------------
 Class MashSoftState/Adaptive -superclass MashSoftState
 
 MashSoftState/Adaptive instproc init { value timeout callback {N 8} } {
     $self next $value $timeout $callback
 
     $self instvar n_
     set n_ $N
 
     $self instvar last_refresh_
     set last_refresh_ [clock clicks -milliseconds]
 
     $self instvar avg_diff_
     set avg_diff_ [expr {$timeout/$N}]
 }
 
 
 #----------------------------------------------------------------------
 # Method:
 #   MashSoftState/Adaptive refresh
 # Description:
 #   Refresh the soft state.
 #----------------------------------------------------------------------
 MashSoftState/Adaptive public refresh { } {
     $self instvar timer_ timeout_ callback_ last_refresh_
     set now [clock clicks -milliseconds]
     set diff [expr {$now - $last_refresh_}]
     set last_refresh_ $now
 
     $self instvar avg_diff_ n_
     set avg_diff_ [expr {0.88*$avg_diff_ + 0.12*$diff}]
 
     set t [expr {$n_*$avg_diff_}]
     $timer_ cancel
     $timer_ sched $t
     #MashLog info "SS: resched: self=$self:to=$t:n=$n_:d=$avg_diff_"
 }
 
 #----------------------------------------------------------------------
 # Method:
 #   MashSoftState/Adaptive timeout
 # Description:
 #   Refresh the soft state.
 #----------------------------------------------------------------------
 MashSoftState/Adaptive public expire { } {
     $self instvar callback_
     #MashLog info "SS: expire: self=$self:cb=$callback_"
     $self next
 }